NMR Restraints Grid
| |
NMR Restraints Grid |
|
Result table
| image | mrblock_id | pdb_id | bmrb_id | cing | stage | position | program | type | subtype |
|
|
519511 |
2ldt   |
17682 | cing | 1-original | 3 | XPLOR/CNS | protocol | structure calculation |
evaluate ($end_count=1) ! set number of structures to be calculated
evaluate ($seed=93869099)
set seed $seed end
{====>}
{====>}
parameter {*Read the parameter file.*}
{====>}
@parnah1er1_mod_new.inp
@par_axis_3.pro
end
evaluate ($knoe = 0.1)
evaluate ($kcdi = 10.0)
evaluate ($kori = 0.002)
evaluate ($knuc = 0.002)
{====>} structure @h27_912-888_H2.psf @axis_new.psf end {*Read the structure file.*}
coor @../xplor_stuff/912-888/912-888_calcs/"test27_1_912-888_calcs_xxx.pdb"
flags exclude * include bonds angles impr end
mini powell nstep=100 step=1.0 end
coor copy end
@plane_888.inp
@rna_orient_888.setup
noe
{====>}
nres=3000 {*Estimate greater than the actual number of NOEs.*}
class all
{====>}
@noe_912-888_inter.tbl
@noe_912-888_intra.tbl {*Read NOE distance ranges.*}
class hb
@hbond_912-888.tbl
end
{====>}
restraints dihed
scale $kcdi
nass = 5000
set message on echo on end
@912-888_chiral.tbl
@aform_912-888.tbl
@c2_912-888.tbl
@c3_912-888.tbl
@chi_912-888.tbl !dihedral angle restraints.
set message on echo on end
end
noe {*Parameters for NOE effective energy term.*}
ceiling=1000
averaging all sum
potential all square
sqconstant all 1.
sqexponent all 2
scale all $knoe {*Constant NOE scale throughout the protocol.*}
averaging hb sum
potential hb biharmonic
sqconstant hb 1.
sqexponent hb 2
scale hb $knoe {*Constant NOE scale throughout the protocol.*}
end
evaluate ($knuc=0.1)
rama
nres=10000
set message off echo off end
@nucleic_deltor_quarts2d.tbl
@nucleic_deltor_quarts3d.tbl
@nucleic_deltor_quarts4d.tbl
@force_nucleic_quarts2d.tbl
@force_nucleic_quarts3d.tbl
@force_nucleic_quarts4d.tbl
end
set message on echo on end
@setup_nucleic_2d3d.tbl
@setup_nucleic_4d.tbl
set message on echo on end
evaluate ($ini_sani = 0.001)
evaluate ($ksani = $ini_sani)
sani
nres=500
class JCHw ! allRDCs
force $ksani
potential harmonic
coeff 0.0 -27.05 0.196
@dip_70_888_allRDCs.tbl
class JCHf ! allRDCs
force 0.0 !$ksani
potential harmonic
coeff 0.0 -27.05 0.196
@dip_30_888_allRDCs.tbl
end
parameter {*Parameters for the repulsive energy term.*}
nbonds
cutnb=6.5
rcon=4.0 nbxmod=3 repel=0.8 rexp=2 irex=2
wmin=0.01 tolerance=0.5
end
end
vector do (store1 = decode(resid)) (name C3')
vector show min (store1) (name C3')
evaluate ($first_residue = $result)
vector show max (store1) (name C3')
evaluate ($last_residue = $result)
dynamics internal
group (resid 500 )
hinge rotate (resid 500)
evaluate ($res = 1)
while ($res le 34) loop group
group (resid $res and resname CYT and
(name n1 or name c6 or name c5 or name c4
or name n3 or name c2))
group (resid $res and resname GUA and
(name n9 or name c4 or name n3 or name c2 or name n1 or
name c6 or name c5 or name n7 or name c8))
group (resid $res and resname ADE and
(name n9 or name c4 or name n3 or name c2 or name n1 or
name c6 or name c5 or name n7 or name c8))
group (resid $res and resname THY and
(name n1 or name c6 or name c5 or name c4
or name n3 or name c2))
group (resid $res and resname URI and
(name n1 or name c6 or name c5 or name c4
or name n3 or name c2))
evaluate ($res = $res +1)
end loop group
group (resid 34 and (name n1 or name c1 or name c2 or name o2
or name n3 or name c3 or name c4 or name n9 or name c8
or name n7 or name c5 or name c6 or name o6 or name h7))
set message on echo on end
cloop=false
auto torsion
maxe 10000
end
evaluate ($cool_steps = 3000)
evaluate ($init_t = 2000.01)
evaluate ($tol = $init_t/1000)
vector do (mass = 100.0) (all)
vector do (fbeta = 10.0) (all)
{====>}
evaluate ($count = 0)
while ($count < $end_count ) loop structure
evaluate ($count=$count+1)
{====>} {*Filename(s) for embedded coordinates.*}
vector do (x=xcomp) (all)
vector do (y=ycomp) (all)
vector do (z=zcomp) (all)
evaluate ($ini_rad = 0.9) evaluate ($fin_rad = 0.78)
evaluate ($ini_con= 0.004) evaluate ($fin_con= 4.0)
evaluate ($rcon=$ini_con)
evaluate ($ini_ang = 1.0) evaluate ($fin_ang = 1.0)
evaluate ($ini_imp = 1.0) evaluate ($fin_imp = 1.0)
evaluate ($ini_noe = 2.0) evaluate ($fin_noe = 30.0)
evaluate ($knoe = $ini_noe)
evaluate ($ini_nuc = 0.5) evaluate ($fin_nuc = 1.0)
evaluate ($knuc = $ini_nuc)
evaluate ($ini_orie = 0.002) evaluate ($fin_orie = 0.30)
evaluate ($korie = $ini_orie)
evaluate ($ini_sani = 0.01) evaluate ($fin_sani = 1.0)
evaluate ($ksani = $ini_sani)
evaluate ($kcdi = 10.0) ! torsion angles
noe scale * $knoe end
evaluate ($ksanib = $ksani)
sani class JCHw force $ksani end
restraints dihed
scale $kcdi
end
rama
@force_nucleic_quarts2d.tbl
@force_nucleic_quarts3d.tbl
@force_nucleic_quarts4d.tbl
end
orie scale $korie end
evaluate ($rcon = 1.0)
parameters
nbonds
atom
nbxmod 3
wmin = 0.01 ! warning off
cutnb = 100 ! nonbonded cutoff
tolerance 45
repel= 1.2 ! scale factor for vdW radii = 1 ( L-J radii)
rexp = 2 ! exponents in (r^irex - R0^irex)^rexp
irex = 2
rcon=$rcon ! actually set the vdW weight
end
end
flags exclude * include bond angl impr vdw noe cdih plan sani orie rama end !orie rama
constraints
interaction (not name c1' ) (all)
weights * 1 angl 0.4 impr 0.1 vdw 0 elec 0 end
interaction (name c1') (name c1')
weights * 1 angl 0.4 impr 0.1 vdw 1.0 end
end
vector do (vx = maxwell($init_t)) (all)
vector do (vy = maxwell($init_t)) (all)
vector do (vz = maxwell($init_t)) (all)
dynamics internal
itype=pc6
!maxe=100
etol=$tol
tbath=$init_t
response= 20
response= 5
nstep=5000
timestep= 0.002
endtime=10
end
parameters
nbonds
atom
nbxmod 3
wmin = 0.01 ! warning off
cutnb = 4.5 ! nonbonded cutoff
tolerance 0.5
repel= 0.9 ! scale factor for vdW radii = 1 ( L-J radii)
rexp = 2 ! exponents in (r^irex - R0^irex)^rexp
irex = 2
rcon =1.0 ! actually set the vdW weight
end
end
evaluate ($kcdi = 200)
restraints dihed
scale $kcdi
end
evaluate ($final_t = 25) { K }
evaluate ($tempstep = 25) { K }
evaluate ($ncycle = ($init_t-$final_t)/$tempstep)
evaluate ($nstep = int($cool_steps*4.0/$ncycle))
evaluate ($endtime = $nstep*0.002)
evaluate ($bath = $init_t)
evaluate ($k_vdw = $ini_con)
evaluate ($k_vdwfact = ($fin_con/$ini_con)^(1/$ncycle))
evaluate ($radius= $ini_rad)
evaluate ($radfact = ($fin_rad/$ini_rad)^(1/$ncycle))
evaluate ($k_ang = $ini_ang)
evaluate ($ang_fac = ($fin_ang/$ini_ang)^(1/$ncycle))
evaluate ($k_imp = $ini_imp)
evaluate ($imp_fac = ($fin_imp/$ini_imp)^(1/$ncycle))
evaluate ($noe_fac = ($fin_noe/$ini_noe)^(1/$ncycle))
evaluate ($knoe = $ini_noe)
!evaluate ($rama_fac = ($fin_rama/$ini_rama)^(1/$ncycle))
evaluate ($nuc_fac = ($fin_nuc/$ini_nuc)^(1/$ncycle))
evaluate ($knuc = $ini_nuc)
evaluate ($orie_fac = ($fin_orie/$ini_orie)^(1/$ncycle))
evaluate ($korie = $ini_orie)
evaluate ($sani_fac = ($fin_sani/$ini_sani)^(1/$ncycle))
evaluate ($ksani = $ini_sani)
evaluate ($ksanib = $ksani)
evaluate ($ksanin = $ksani*1.0)
evaluate ($ksanim = $ksani*1.0)
evaluate ($ksaddr = $ksani*1/5)
evaluate ($ksaddb = $ksani*1/8)
sani class JCHw force $ksani end
flags exclude * include bond angl impr vdw noe cdih plan sani orie rama end
vector do (vx = maxwell($bath)) (all)
vector do (vy = maxwell($bath)) (all)
vector do (vz = maxwell($bath)) (all)
evaluate ($i_cool = 0)
while ($i_cool < $ncycle) loop cool
evaluate ($i_cool=$i_cool+1)
evaluate ($bath = $bath - $tempstep)
evaluate ($k_vdw=min($fin_con,$k_vdw*$k_vdwfact))
evaluate ($radius=max($fin_rad,$radius*$radfact))
evaluate ($k_ang = $k_ang*$ang_fac)
evaluate ($k_imp = $k_imp*$imp_fac)
evaluate ($knoe = $knoe*$noe_fac)
evaluate ($knuc = $knuc*$nuc_fac)
evaluate ($korie = $korie*$orie_fac)
evaluate ($ksani = $ksani*$sani_fac)
evaluate ($ksanib = $ksani)
evaluate ($ksanin = $ksani*1.0)
evaluate ($ksanim = $ksani*1.0)
evaluate ($ksaddr = $ksani*1/5)
evaluate ($ksaddb = $ksani*1/8)
sani class JCHw force $ksani end
constraints interaction (all) (all) weights
* 1 angles $k_ang improper $k_imp
end end
parameter
nbonds
cutnb=4.5 rcon=$k_vdw nbxmod=3 repel=$radius
end end
noe scale * $knoe end
rama
@force_nucleic_quarts2d.tbl
@force_nucleic_quarts3d.tbl
@force_nucleic_quarts4d.tbl
end
orie scale $korie end
dynamics internal
itype=pc6
!maxe=100
etol=$tol
tbath=$bath
response= 20
response= 5
nstep=$nstep
endtime=$endtime
timestep= 0.002
end
end loop cool
dynamics internal
itype=powell
nstep=200
maxcalls=20000
nprint=1
etol=1e-7
gtol=0.01
depred=0.001
end
{* =================================== Write out the final structure(s).*}
print threshold=0.5 noe
evaluate ($rms_noe=$result)
evaluate ($violations_noe=$violations)
print threshold=5. cdih
evaluate ($rms_cdih=$result)
evaluate ($violations_cdih=$violations)
print thres=0.05 bonds
evaluate ($rms_bonds=$result)
print thres=5. angles
evaluate ($rms_angles=$result)
print thres=5. impropers
evaluate ($rms_impropers=$result)
sani print threshold=5.0 class JCHw end
evaluate ($rms_JCHw=$result)
evaluate ($R_JCHw=$result*100/23.86)
sani print threshold=5.0 class JCHf end
evaluate ($rms_JCHf=$result)
evaluate ($R_JCHf=$result*100/23.86)
remarks ===============================================================
remarks overall,bonds,angles,improper,vdw,noe,cdih,rama,orie,plan,sani,orie
remarks energies: $ener, $bond, $angl, $impr, $vdw, $noe, $cdih, $plan, $sani, $orie
remarks ===============================================================
remarks bonds,angles,impropers,noe,cdih
remarks rms-d: $rms_bonds,$rms_angles,$rms_impropers,$rms_noe,$rms_cdih
remarks ===============================================================
remarks noe, cdih
remarks violations.: $violations_noe, $violations_cdih
remarks ===============================================================
remarks R-factor: JCH_work (70%) JCH_free (30%)
remarks R-factor sani: $R_JCHw $R_JCHf
remarks rms sani: $rms_JCHw $rms_JCHf
remarks ===============================================================
{====>} {*Name(s) of the family of final structures.*}
evaluate ($filename="test27_xxx_allRDCs.sa")
write coordinates output =$filename end
end loop structure
stop
Contact the webmaster for help, if required. Wednesday, April 24, 2024 8:17:54 AM GMT (wattos1)