! dg.inp -- Full metric matrix distance geometry
! Dave Schweisguth , 7 May 1996
! Derived from nmr/dg_full_embed.inp
set seed=@xplor.seed end ! Use 'xplor -s'
set echo=off message=off end ! Normal use
!set echo=on message=all end ! Auxiliary file debugging
structure @rsf.inp end
parameter @XPLORLIB:toppar/dna-rna-allatom.par end
! Uncomment the following to define rigid groups (which seem to do nothing)
!coordinates disposition=main @template.pdb ! END in PDB file
noe nres=1000 @noes.stem.inp @noes.loop.inp @base-pairs.inp end
restraints dihedral nassign=300 @dihedrals.inp end
set echo=on message=all end
! Include NOE and dihedral restraints in mmdg
flags exclude * include bond angle dihe impr vdw noe cdih end
parameter nbonds repel=0.8 end end ! Scale van der Waals radii
mmdg
! @groups.inp ! Uncomment to define rigid groups
! (which seem to do nothing)
selection=(all)
storebounds
end
! Loop until embedding is successful. Once usually suffices.
evaluate ($embedded="false")
while ($embedded="false") loop embed
mmdg recallbounds end
end loop embed
! Scale coordinates by $dgscale (defined by mmdg)
vector do (x = x * $dgscale) (known)
vector do (y = y * $dgscale) (known)
vector do (z = z * $dgscale) (known)
! Regularize
flags exclude * include dg end
minimize powell nstep=100 drop=10 nprint=25 end
write coordinates output=dg.pdb end
stop
! dgsa.inp -- Clean up the output of dg.inp using simulated annealing
! Dave Schweisguth , 22 Jul 1996
! Derived from nmr/dgsa.inp
evaluate ($init_t=3000) ! Temperature for constant-temperature MD
evaluate ($high_steps=6000) ! Number of steps at high temp
evaluate ($high_timestep=0.002) ! Time of each MD step at high temp
evaluate ($final_t=300) ! Final temperature
evaluate ($cool_steps=7500) ! Number of steps for cooling
evaluate ($cool_timestep=0.002) ! Time of each MD step when cooling
evaluate ($tempstep=50) ! Degree increment for cooling
set seed=@xplor.seed end ! Use 'xplor -s'
set echo=off message=off end ! Normal use
!set echo=on message=all end ! Auxiliary file debugging
structure @rsf.inp end
parameter @XPLORLIB:toppar/dna-rna-allatom.par end
noe nres=1000 @noes.stem.inp @noes.loop.inp @base-pairs.inp end
restraints dihedral nassign=300 @dihedrals.inp end
evaluate($planarweight=50) ! AAFS' choice
restraints planar @planars.inp end
set echo=on message=all end
vector do (fbeta=10) (all) ! Friction coeff. for MD heatbath, in 1/ps.
vector do (mass=100) (all) ! Uniform heavy masses to speed MD.
noe ! Parameters for NOE effective energy term.
ceiling=1000
averaging * cent
potential * square
sqconstant * 1
sqexponent * 2
scale * 100 ! Constant NOE scale throughout the protocol.
end
parameter ! Parameters for the repulsive energy term.
nbonds
repel=0.5 ! Initial value for repel--modified later.
rexp=2
irexp=2
rcon=1
nbxmod=-2 ! Initial value for nbxmod--modified later.
wmin=0.01
cutnb=4.5
ctonnb=2.99
ctofnb=3
tolerance=0.5
end
end
! Test for the correct enantiomer; if you want to bypass this test because
! the substructures were tested previously, simply remove the -1 from the
! next statement.
for $image in (1 -1) loop imag
coordinates initialize end
coordinates @dg.pdb ! END in PDB file
vector do (x=x * $image) (known)
vector identity (store1) (not known) ! Set store1 to unknowns.
! Create local ideal geometry by template fitting;
! this also takes care of unknown atoms.
coordinates copy end ! Store current coordinates in comparison set.
coordinates initialize end
coordinates @template.pdb ! END in PDB file
set echo=off message=off end
for $id in id (tag) loop fit ! Loop over residue tags.
! LSQ fitting using known coordinates.
coordinates fit selection=(byresidue (id $id) and not store1) end
! Store fitted template coordinates for this residue.
coordinates copy selection=(byresidue (id $id)) end
end loop fit
set echo=on message=all end
coordinates swap end
! Minimization of bonds, VDWs, and NOEs.
flags exclude * include bond vdw noe cdih plan end
constraints interaction (all) (all) weights * 1 vdw 20 end end
parameter nbonds nbxmod=-2 repel=0.5 end end
restraints dihedral scale=20 end
minimize powell drop=10 nstep=300 nprint=10 end
! Include angles.
flags include angl end
minimize powell drop=10 nstep=300 nprint=10 end
! Dynamics, slowly introducing dihedral and improper angles
flags include dihe impr end
evaluate ($nstep1=int($high_steps/8)) ! Dynamics runs 1, 2, 3 and 5
evaluate ($nstep2=int($high_steps/2)) ! Dynamics run 4
constraints inter (all) (all) weights * 0.1 dihe 0.05 impr 0.05 vdw 20 end end
dynamics verlet
nstep=$nstep1 time=$high_timestep iasvel=maxwell firstt=$init_t
tcoup=true tbath=$init_t nprint=100 iprfrq=0
end
constraints inter (all) (all) weights * 0.2 dihe 0.1 impr 0.1 vdw 20 end end
dynamics verlet
nstep=$nstep1 time=$high_timestep iasvel=current firstt=$init_t
tcoup=true tbath=$init_t nprint=100 iprfrq=0
end
constraints inter (all) (all) weights * 0.2 dihe 0.2 impr 0.2 vdw 0.01 end end
parameter nbonds repel=0.9 end end
dynamics verlet
nstep=$nstep1 time=$high_timestep iasvel=current firstt=$init_t
tcoup=true tbath=$init_t nprint=100 iprfrq=0
end
constraints inter (all) (all) weights * 0.4 dihe 0.4 impr 0.4 vdw 0.003 end end
parameter nbonds nbxmod=-3 end end
dynamics verlet
nstep=$nstep2 time=$high_timestep iasvel=current firstt=$init_t
tcoup=true tbath=$init_t nprint=100 iprfrq=0
end
constraints inter (all) (all) weights * 1 dihe 1 impr 1 vdw 0.003 end end
dynamics verlet
nstep=$nstep1 time=$high_timestep iasvel=current firstt=$init_t
tcoup=true tbath=$init_t nprint=100 iprfrq=0
end
if ($image=1) then
vector do (store7=x) (all) ! Store first image in stores.
vector do (store8=y) (all)
vector do (store9=z) (all)
vector do (store4=vx) (all)
vector do (store5=vy) (all)
vector do (store6=vz) (all)
end if
end loop imag
! Establish the correct handedness of the structure.
energy end
evaluate ($e_minus=$ener)
coordinates copy end
vector do (x=store7) (all)
vector do (y=store8) (all)
vector do (z=store9) (all)
energy end
evaluate ($e_plus=$ener)
if ($e_plus > $e_minus) then
evaluate ($hand=-1)
coordinates swap end
else
evaluate ($hand=1)
vector do (vx=store4) (all)
vector do (vy=store5) (all)
vector do (vz=store6) (all)
end if
! Increase VDW interaction and cool.
restraints dihedral scale=800 end
evaluate ($bath=$init_t)
evaluate ($ncycle=($init_t-$final_t)/$tempstep)
evaluate ($nstep=int($cool_steps/$ncycle))
evaluate ($ini_rad=0.9)
evaluate ($fin_rad=0.75)
evaluate ($radius=$ini_rad)
evaluate ($radfact=($fin_rad/$ini_rad)^(1/$ncycle))
evaluate ($ini_con=0.003)
evaluate ($fin_con=4.0)
evaluate ($k_vdw=$ini_con)
evaluate ($k_vdwfact=($fin_con/$ini_con)^(1/$ncycle))
evaluate ($i_cool=0)
while ($i_cool < $ncycle) loop cool
evaluate ($i_cool=$i_cool+1)
evaluate ($bath=$bath - $tempstep)
evaluate ($radius=max($fin_rad,$radius*$radfact))
evaluate ($k_vdw=min($fin_con,$k_vdw*$k_vdwfact))
parameter nbonds repel=$radius end end
constraints interaction (all) (all) weights * 1 vdw $k_vdw end end
dynamics verlet
nstep=$nstep time=$cool_timestep iasvel=current firstt=$bath
tcoup=true tbath=$bath nprint=$nstep iprfrq=0
end
! Abort condition.
evaluate ($critical=$temp/$bath)
if ($critical > 10) then
display Rerun job with smaller timestep (i.e., 0.003)
stop
end if
end loop cool
! Final minimization.
minimize powell drop=10 nstep=600 nprint=25 end
! Analyze and write out the final structure.
print threshold=0.05 bonds
evaluate ($rms_bond=$result)
evaluate ($v_bond=$violations)
print threshold=5 angles
evaluate ($rms_angl=$result)
evaluate ($v_angl=$violations)
print threshold=15 dihedrals
evaluate ($rms_dihe=$result)
evaluate ($v_dihe=$violations)
print threshold=5 impropers
evaluate ($rms_impr=$result)
evaluate ($v_impr=$violations)
print threshold=0.2 noe
evaluate ($rms_noe=$result)
evaluate ($v_noe=$violations)
print threshold=5 cdih
evaluate ($rms_cdih=$result)
evaluate ($v_cdih=$violations)
set echo=off message=off end
display Energy: bond $bond, angle $angl, dihedral $dihe,
display improper $impr, NOE $noe, c-dihedral $cdih,
display planar $plan, VdW $vdw, total $ener
display RMSD: bond $rms_bond, angle $rms_angl, dihedral $rms_dihe,
display improper $rms_impr, NOE $rms_noe, c-dihedral $rms_cdih
display Violations: bond $v_bond, angle $v_angl, dihedral $v_dihe,
display improper $v_impr, NOE $v_noe, c-dihedral $v_cdih
display Handedness $hand, enantiomer discrimination $e_plus:$e_minus
set echo=on message=all end
write coordinates output=dgsa.pdb end
stop
Please acknowledge these references
in publications where the data from this site have been utilized.
Contact the webmaster for help, if required. Thursday, April 18, 2024 11:51:24 PM GMT
(wattos1)
